llSensorRepeat ("", "", AGENT, 0.001, 0.0, time);

llSensorRepeat ("", llGetKey(), AGENT, 0.001, 0.0, time);

//Compound timer

//These three functions enable you to set up multiple timer events, each with their own interval, simultaneously
//(In this example you can trigger a simple dialog by clicking and holding for one second)

//list of timer events
list timer_events;//strided 3: next event due time, event id, interval between events

//store the returned key to identify this particular event in the timer () event
//specify the interval between triggering of the timer () event
key SetTimerEvent (float interval)
{
    //convert negative and zero intervals to immediate (use a seperate function to stop timer events)
    if (interval <= 0.0) interval = 0.01;
    //create a (hopefully) unique UUID for this event
    key id = (key) llInsertString (llInsertString (llInsertString (llInsertString (llMD5String (llGetTimestamp (), 0), 8, "-"), 13, "-"), 18, "-"), 23, "-");
    //add this event to the list and sort the list
    timer_events = llListSort ([llGetTime () + interval, id, interval] + timer_events, 3, TRUE);
    //calculate how long till the next event
    interval = llList2Float (timer_events, 0) - llGetTime ();
    //if we're already late for the next event do it immediately
    if (interval <= 0.0) interval = 0.01;
    //wait until the next event is due
    llSetTimerEvent (interval);
    return id;
}

//use a stored event key to specify it for removal
StopTimerEvent (key id)
{
    //find this event in the list
    integer index = llListFindList (timer_events, [id]);
    //if it's there...
    if (index > -1)
    {
        //remove this event from the list
        timer_events = llDeleteSubList (timer_events, index - 1, index + 1);
        //if there's no events left in the list stop the timer
        if (llGetListLength (timer_events) == 0) llSetTimerEvent (0.0);
        //if there are, and we've just removed the next scheduled event...
        else if (index == 1)
        {
            //calculate how long till the next event
            float interval = llList2Float (timer_events, 0) - llGetTime ();
            //if we're already late for it do it immediately
            if (interval <= 0.0) interval = 0.01;
            //wait until it's due
            llSetTimerEvent (interval);
        }
    }
}

//get the UUID of the current event in the timer () event to identify which event it is responding to
key GetTimerEventKey ()
{
    //get the UUID for the current event
    key id = llList2Key (timer_events, 1);
    //get the timer interval for this event
    float interval = llList2Float (timer_events, 2);
    //replace the current event with it's next ocurrence and sort the list
    timer_events = llListSort (llListReplaceList (timer_events, [llGetTime () + interval, id, interval], 0, 2), 3, TRUE);
    //calculate how long till the next event
    interval = llList2Float (timer_events, 0) - llGetTime ();
    //if we're already late for the next event do it immediately
    if (interval <= 0.0) interval = 0.01;
    //wait until the next event is due
    llSetTimerEvent (interval);
    return id;
}

//UUIDs of example timer events
key regular_timer;
key touch_timer;
key long_touch_timer;
key dialog_timeout;

//flag for when a long click-and-hold is encountered
integer long_touch;
//listener for dialog response
integer listener;

default
{
    state_entry ()
    {
        //set up a regular timer event (switchable on/off by dialog)
        regular_timer = SetTimerEvent (10.0);
    }
    touch_start (integer count)
    {
        if (llDetectedKey (0) == llGetOwner ())//ignore curious bystanders
        {
            //set up a timer to see if this is a long click-and-hold
            long_touch_timer = SetTimerEvent (1.0);
        }
    }
    touch_end (integer count)
    {
        if (llDetectedKey (0) == llGetOwner ())//ignore curious bystanders
        {
            //if this was a long click-and-hold reset the flag and do nothing else
            if (long_touch) long_touch = FALSE;
            //otherwise this was just a normal click...
            else
            {
                //stop waiting for a long click-and-hold
                StopTimerEvent (long_touch_timer);
                //precess the result of a normal click (in this case, trigger an event in 5s time)
                touch_timer = SetTimerEvent (5.0);
            }
        }
    }
    timer ()
    {
        //get the UUID of the current event
        key event_id = GetTimerEventKey ();
        //process the different events according to their UUID...
        if (event_id == regular_timer) llOwnerSay ("Regular 10s timer.");//the regular timer
        else if (event_id == touch_timer)//triggered 5s after a normal click
        {
            //stop further occurences of this event
            StopTimerEvent (touch_timer);
            //process the event
            llOwnerSay ("Touch triggered 5s timer.");
        }
        else if (event_id == long_touch_timer)//triggered 1s after a click that hasn't yet been released
        {
            //stop further occurences of this event
            StopTimerEvent (long_touch_timer);
            //set the flag so nothing happens in the touch_end () event
            long_touch = TRUE;
            //open a listener for the dialog
            listener = llListen (-5678, "", llGetOwner (), "");
            //initiate the dialog
            llDialog (llGetOwner (), "\nRegular timer:", llList2List (["Stop", "Start"], regular_timer == NULL_KEY, regular_timer == NULL_KEY) + ["CANCEL"], -5678);
            //create an event for a dialog timeout
            dialog_timeout = SetTimerEvent (60.0);
        }
        else if (event_id == dialog_timeout)//triggered 60s after a dialog has been initated but not responded to
        {
            //stop further occurences of this event
            StopTimerEvent (dialog_timeout);
            //remove the listener
            llListenRemove (listener);
            //kill the original dialog with a timeout info message (this works great in V2/3 viewers, maybe not no great elsewhere)
            llDialog (llGetOwner (), "\nDialog timeout", [], -999);
        }
        else
        {
            //this event hasn't been recognised so remove it from the list (you could try and do something about it, but here we'll just forget about it)
            //(in this example this can happen after multiple normal clicks, each overriding the previously stored UUID for a normal click)
            StopTimerEvent (event_id);
            //unnecessary spam
            llOwnerSay ("Unprocessed timer event.");
        }
    }
    listen (integer channel, string name, key id, string message)
    {
        //we've had a response to the dialog so we won't want a dialog timeout 
        StopTimerEvent (dialog_timeout);
        //remove the listener
        llListenRemove (listener);
        //process the dialog message...
        if (message == "Start")
        {
            //start a regular timer
            regular_timer = SetTimerEvent (10.0);
            //unnecessary spam
            llOwnerSay ("Starting regular timer.");
        }
        else if (message == "Stop")
        {
            //stop the regular timer
            StopTimerEvent (regular_timer);
            //specifically set NULL_KEY to simplify selecting which button to display in the dialog
            regular_timer = NULL_KEY;
            //unnecessary spam
            llOwnerSay ("Stopping regular timer.");
        }
        //do nothing: either the dialog has been cancelled deliberately, or a spurious message has managed to sneak in
        //unnecessary spam
        else llOwnerSay (message + " – dialog cancelled.");
    }
}

changed(integer poot)
{
   if(poot & CHANGED_COLOR)
   {
      llSetColor(<llFrand(1), 0, 0>, 0);
      code();
   }
}