//v1.0
//   released
//v1.1
//   Switch to Do-While instead of For
//   Moved greet spam to inside of If (oops)
//   Optimized list addition for LSO
//   Upped scan rate to 15.0s

string greeting1 = "Hello,";
string greeting2 = "Please click me if you'd like an informational notecard.";

string greeting_for_no_note = "I'm sorry, I seem to have run out of notecards, please enjoy your visit";

string notecard;
key owner;
integer Handler;
integer channel;

GetNoteCardName()
{
    notecard = llGetInventoryName(INVENTORY_NOTECARD,0);
    if(notecard == "")
    {
        llOwnerSay("ERROR: No notecard in inventory!");
    }
    
}
DeliverNote(key ID)
{
    if(notecard != "")
    {
        llGiveInventory(ID,notecard);
    }
    else
    {
        llSay(0,"greeting_for_no_note");
    }
}

list visitors;
string notecardname;

default
{
    state_entry()
    {
        owner = llGetOwner();
        llSensorRepeat("",NULL_KEY,AGENT,96.0,PI,15.0);
        GetNoteCardName();
        channel =(integer)("0x"+llGetSubString(owner,27,30));
    }
    sensor(integer ND)
    {
        --ND; //we want N-1 because the detected is 0 to N-1, not 1 to N
        do
        {
            string testname =llDetectedName(ND);
            if(llListFindList(visitors,[testname]) == -1) //if not in list
            {
                // for LSO, optimal is myList = (myList=[]) + myList + new_item;
                visitors = (visitors=[]) + visitors + testname;
                llSay(0,greeting1+" "+testname+" "+greeting2);
                // Keep list short to avoid memory issues.
                if(llGetListLength(visitors) > 64) 
                {
                    visitors = llDeleteSubList(visitors,0,0);
                }
            }
        }
        while((--ND) >= 0);
    }
    changed(integer C)
    {
        if(C & CHANGED_INVENTORY)
        {
            GetNoteCardName();
        }
    }
    touch_start(integer T)
    {
        if(llDetectedKey(0) == owner)
        {
            llDialog(owner,"Pick an Option:",["Test","Reset"],channel);
            llSetTimerEvent(30.0);
            Handler = llListen(channel,"",owner,"");  
        }
        else DeliverNote(llDetectedKey(0));
    }
    listen(integer ch,string name, key id,string txt)
    {
        if(txt == "Test")
        {
           DeliverNote(owner);
        }
        else if (txt = "Reset")
        {
            llResetScript();
        }
        llSetTimerEvent(0.0);
        llListenRemove(Handler);
    }
    timer()
    {
        llListenRemove(Handler);
        llOwnerSay("Timed out while waiting for response, click again for menu.");
        llSetTimerEvent(0.0);
    }
    on_rez(integer R)
    {
        if(owner != llGetOwner())
        {
            llResetScript();
        }
    } 
             
              
}